翻訳：株式会社サムライズ
ADOBE® MEDIA SERVER 5.0.3
デベロッパーズガイド
|
|
翻訳：株式会社サムライズ |
|---|
注意
Adobe Media Server® バージョン 5についての本ドキュメントは第三者によって翻訳されたものであり、Adobe Systems Incorporated（アドビ システムズ社）は本翻訳物の正確性や完全性を査閲していません。
例：Hello World アプリケーション
注意：Adobe Media Server Standard に対してはサーバーサイドコードを記述できないので、以下の節の内容はそのエディションのサーバーには該当しません。
このサンプルでは、クライアントからサーバーおよびサーバーからクライアントへのシンプルな通信を示します。ユーザーがボタンをクリックすると、クライアントはサーバーに接続します。クライアントは、文字列を返すサーバーサイドの関数を呼び出します。サーバーが応答すると、クライアントはサーバーから送信された文字列を表示します。
サンプルファイルは、rootinstall\documentation\samples\HelloWorld フォルダーにあります。
1 Flash を起動し、新規作成／ Flash ファイル（ActionScript 3.0）を選択します。
2 「ドキュメントクラス」フィールドに、HelloWorld と入力します。定義が欠けているのに関する ActionScript クラスの警告メッセージが表示された場合、「OK」をクリックします。次のセクションでは、クラスファイルを追加します。
3 ウインドウ／コンポーネントを選択します。「User Interface」をクリックし、Button ダブルクリックして stage 追加します。「プロパティ」タブで、インスタンス名として connectBtn と入力します。
4 ボタンの上に Label コンポーネントを追加し、インスタンス名として textLbl と入力します。
5 HelloWorld.fla という名前を付けてこのファイルを保存します。
クライアントファイルは、任意の場所に保存できます。
このスクリプトは、ボタンの2 つのアクション（サーバーへの接続とサーバーからの切断）を提供します。このスクリプトは、接続時に文字列（「World」）を使用してサーバーを呼び出し、応答をトリガーします。この応答によって返された文字列（「Hello, World!」）が表示されます。
1 ファイル／新規／ ActionScript ファイルを選択します。「Target」テキストボックスに HelloWorld.fla と表示されていることを確認します。
2 パッケージを宣言して、必要な Flash クラスを読み込みます。
package {
import flash.display.MovieClip;
import flash.net.Responder;
import flash.net.NetConnection;
import flash.events.NetStatusEvent;
import flash.events.MouseEvent;
public class HelloWorld extends MovieClip {
}
}
3 HelloWorld クラスの宣言内で、接続およびサーバー応答の変数を宣言します。
private var nc:NetConnection;
private var myResponder:Responder = new Responder(onReply);
4 クラスのコンストラクターを定義します。ラベルとボタンの表示値を設定し、ボタンにイベントリスナーを追加します。
public function HelloWorld() {
textLbl.text = "";
connectBtn.label = "Connect";
connectBtn.addEventListener(MouseEvent.CLICK, connectHandler);
}
5 イベントリスナーのアクションを定義します。このアクションは、その時点のボタンのラベルによって異なります。
public function connectHandler(event:MouseEvent):void {
if (connectBtn.label == "Connect") {
trace("Connecting...");
nc = new
NetConnection();
// Connect to the server.
nc.connect("rtmp://localhost/HelloWorld");
// Call the server's client function serverHelloMsg, in HelloWorld.asc.
nc.call("serverHelloMsg", myResponder, "World");
connectBtn.label = "Disconnect";
} else {
trace("Disconnecting...");
// Close the connection.
nc.close();
connectBtn.label = "Connect";
textLbl.text = "";
}
}
6 応答関数を定義します。この関数により、ラベルの表示値を設定します。
private function onReply(result:Object):void {
trace("onReply received value: " + result);
textLbl.text = String(result);
}
7 ファイルを HelloWorld.fla ファイルと同じフォルダーに、HelloWorld.as という名前で保存します。
1 ファイル／新規／ ActionScript コミュニケーションファイルを選択します。
2 サーバーサイド関数と接続ロジックを定義します。
application.onConnect = function( client ) {
client.serverHelloMsg = function( helloStr ) {
return "Hello, " + helloStr + "!";
}
application.acceptConnection( client );
}
3 rootinstall/applications/HelloWorld フォルダー内に、HelloWorld.asc という名前を付けてこのファイルを保存します。ファイルを保存するときに、HelloWorld フォルダーを作成します。
1 サーバーの実行状態の確認 .
2 HelloWorld.fla ファイルのタブを選択します。
3 制御／ムービープレビューを選択します。
4 「戻る」ボタンをクリックします。
「Hello, World!」と表示され、ボタンのラベルが「Disconnect」に変わります。
5 「戻る」ボタンをクリックします。
Flash 出力ウィンドウに、trace() ステートメントの出力が表示されます。
最終更新日 2013/9/30